bloglang/11/examples/primes.txt

data List = { Nil, Cons Nat List }
data Bool = { True, False }
data Nat = { O, S Nat }

defn if c t e = {
    case c of {
        True -> { t }
        False -> { e }
    }
}

defn toInt n = {
    case n of {
        O -> { 0 }
        S np -> { 1 + toInt np }
    }
}

defn lte n m = {
    case m of {
        O -> {
            case n of {
                O -> { True }
                S np -> { False }
            }
        }
        S mp -> {
            case n of {
                O -> { True }
                S np -> { lte np mp }
            }
        }
    }
}

defn minus n m = {
    case m of {
        O -> { n }
        S mp -> { 
            case n of {
                O -> { O }
                S np -> {
                    minus np mp
                }
            }
        }
    }
}

defn mod n m = {
    if (lte m n) (mod (minus n m) m) n
}

defn notDivisibleBy n m = {
    case (mod m n) of {
        O -> { False }
        S mp -> { True }
    }
}

defn filter f l = {
    case l of {
        Nil -> { Nil }
        Cons x xs -> { if (f x) (Cons x (filter f xs)) (filter f xs) }
    }
}

defn map f l = {
    case l of {
        Nil -> { Nil }
        Cons x xs -> { Cons (f x) (map f xs) }
    }
}

defn nats = {
    Cons (S (S O)) (map S nats)
}

defn primesRec l = {
    case l of {
        Nil -> { Nil }
        Cons p xs -> { Cons p (primesRec (filter (notDivisibleBy p) xs)) }
    }
}

defn primes = {
    primesRec nats
}

defn take n l = {
    case l of {
        Nil -> { Nil }
        Cons x xs -> {
            case n of {
                O -> { Nil }
                S np -> { Cons x (take np xs) }
            }
        }
    }
}

defn head l = {
    case l of {
        Nil -> { O }
        Cons x xs -> { x }
    }
}

defn reverseAcc a l = {
    case l of {
        Nil -> { a }
        Cons x xs -> { reverseAcc (Cons x a) xs }
    }
}

defn reverse l = {
    reverseAcc Nil l
}

defn main = {
    toInt (head (reverse (take ((S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S (S O))))))))))))))))))))))))))))))))))))))))))))))))))))))))))))))))))))))))))))))))))))))))))))))))))))) primes)))
}