blog-static-flake/blog/default.nix

{ stdenv, lib, hugo, fetchgit, pkgs, nodejs, ruby }:

let
  url = "https://dev.danilafe.com/Web-Projects/blog-static.git";
  requiredPackages = import ./required-packages.nix { inherit pkgs nodejs; };
  website = settings: stdenv.mkDerivation {
    name = "blog-static";
    version = settings.rev;
    src = fetchgit {
      inherit url;
      inherit (settings) rev sha256;
    };
    urlSub =
      let
        regexEscape = lib.escape [ "/" "(" ")" "[" "]" "+" "*" "\\" ];
      in
        if (settings ? replaceUrl)
        then (with settings.replaceUrl; "s/${regexEscape from}/${regexEscape to}/g")
        else "";
    publicPath = settings.path;
    extraFlags = if settings.drafts then " -D " else "";
    builder = ./builder.sh;
    converter = ./convert.rb;
    buildInputs = [ hugo requiredPackages.katex (ruby.withPackages (ps: [ ps.nokogiri ])) ];
  };
  rev = "b921ddfc8de1282cc82a0d90b2927bf2a5c0ee68";
  sha256 = "1gg7dq9y1hg14qjlj2w1rn0xjgqw58s8kpd5x6c0wfpwszcm87ji";
  localizationRev = "cd574b43fdddf8b6777610f94897d70697533af9";
  localizationSha256 = "1lv65bllrc605lda5gqgpk4ihhg77qgh1zg60swsllmhh5vawgbn";
in
  {
    english = website {
      inherit rev sha256;
      path = ".";
      drafts = false;
    };
    drafts = {
      english = website {
        inherit rev sha256;
        path = ".";
        drafts = true;
        replaceUrl = {
          from = "https://danilafe.com";
          to = "http://drafts.danilafe.com";
        }; 
      };
      russian = website {
        rev = localizationRev;    
        sha256 = localizationSha256;
        path = "ru";
        drafts = true;
        replaceUrl = {
          from = "https://ru.danilafe.com";
          to = "http://drafts.ru.danilafe.com";
        }; 
      };
    };
  }