blog-static-flake/blog/default.nix

{ stdenv, lib, hugo, fetchgit, pkgs, nodejs, ruby }:

let
  url = "https://dev.danilafe.com/Web-Projects/blog-static.git";
  requiredPackages = import ./required-packages.nix { inherit pkgs nodejs; };
  website = settings: stdenv.mkDerivation {
    name = "blog-static";
    version = settings.rev;
    src = fetchgit {
      inherit url;
      inherit (settings) rev sha256;
    };
    urlSub =
      let
        regexEscape = lib.escape [ "/" "(" ")" "[" "]" "+" "*" "\\" ];
      in
        if (settings ? replaceUrl)
        then (with settings.replaceUrl; "s/${regexEscape from}/${regexEscape to}/g")
        else "";
    publicPath = settings.path;
    extraFlags = if settings.drafts then " -D " else "";
    builder = ./builder.sh;
    converter = ./convert.rb;
    server = ./katexserver.js;
    buildInputs = [
      hugo nodejs
      requiredPackages."katex-0.11.1" requiredPackages.express requiredPackages.body-parser
      (ruby.withPackages (ps: [ ps.nokogiri ]))
    ];
  };
  rev = "60eb50737d535e8ec506b877250d0e4bbfbf1bda";
  sha256 = "1xyppzim3kvawr1bkizwmkbgvb4pxhgnc7gxwjv8sdfcyvbfgz8p";
  localizationRev = "0b5748cc5a19b5d1d78bfcfa58d4027cc10524dd";
  localizationSha256 = "12pqh534z3ppvgzy0a77s9j1qzzmiyxwvlmh5y76pccf32wvi9wz";
in
  {
    english = website {
      inherit rev sha256;
      path = ".";
      drafts = false;
    };
    drafts = {
      english = website {
        inherit rev sha256;
        path = ".";
        drafts = true;
        replaceUrl = {
          from = "https://danilafe.com";
          to = "http://drafts.danilafe.com";
        }; 
      };
      russian = website {
        rev = localizationRev;    
        sha256 = localizationSha256;
        path = "ru";
        drafts = true;
        replaceUrl = {
          from = "https://ru.danilafe.com";
          to = "http://drafts.ru.danilafe.com";
        }; 
      };
    };
  }