blog-static-flake/default.nix

{ stdenv, lib, hugo, fetchgit, pkgs, nodejs, ruby }:

let
  url = "https://dev.danilafe.com/Web-Projects/blog-static.git";
  requiredPackages = import ./required-packages.nix { inherit pkgs nodejs; };
  website = settings: stdenv.mkDerivation {
    name = "blog-static";
    version = settings.rev;
    src = fetchgit {
      inherit url;
      inherit (settings) rev sha256;
      fetchSubmodules = true;
    };
    urlSub =
      let
        regexEscape = lib.escape [ "/" "(" ")" "[" "]" "+" "*" "\\" ];
      in
        if (settings ? replaceUrl)
        then (with settings.replaceUrl; "s/${regexEscape from}/${regexEscape to}/g")
        else "";
    publicPath = settings.path;
    extraFlags = if settings.drafts then " -D " else "";
    builder = ./build/builder.sh;
    converter = ./build/convert.rb;
    server = ./build/katexserver.js;
    buildInputs = [
      hugo nodejs
      requiredPackages."katex-0.11.1"
      requiredPackages.express
      requiredPackages.body-parser
      (ruby.withPackages (ps: [ ps.nokogiri ]))
    ];
  };
  rev = "b3ff2fe135fd57a646d5d3271db64886d745ff8c";
  sha256 = "1nljx2wsc25fciwc5ixmwvf8sx4v9n9brx37dhlr4knsadcp89jy";
  localizationRev = "0b5748cc5a19b5d1d78bfcfa58d4027cc10524dd";
  localizationSha256 = "12pqh534z3ppvgzy0a77s9j1qzzmiyxwvlmh5y76pccf32wvi9wz";
in
  {
    english = website {
      inherit rev sha256;
      path = ".";
      drafts = false;
    };
    drafts = {
      english = website {
        inherit rev sha256;
        path = ".";
        drafts = true;
        replaceUrl = {
          from = "https://danilafe.com";
          to = "http://drafts.danilafe.com";
        }; 
      };
      russian = website {
        rev = localizationRev;    
        sha256 = localizationSha256;
        path = "ru";
        drafts = true;
        replaceUrl = {
          from = "https://ru.danilafe.com";
          to = "http://drafts.ru.danilafe.com";
        }; 
      };
    };
  }