blog-static-flake/lib.nix

{ blog-source, blog-source-localized, pkgs }:

with pkgs;

let
  requiredPackages = import ./required-packages.nix { inherit pkgs nodejs; };
  website = settings: stdenv.mkDerivation {
    name = "blog-static";
    version = settings.source.rev;
    src = settings.source;
    ssl = settings.ssl;
    urlSub =
      let
        regexEscape = lib.escape [ "/" "(" ")" "[" "]" "+" "*" "\\" ];
      in
        if (settings ? replaceUrl)
        then (with settings.replaceUrl; "s/${regexEscape from}/${regexEscape to}/g")
        else "";
    publicPath = settings.path;
    extraFlags = if settings.drafts then " -D " else "";
    builder = ./build/builder.sh;
    converter = ./build/convert.rb;
    server = ./build/katexserver.js;
    buildInputs = [
      hugo nodejs
      requiredPackages."katex-0.11.1"
      requiredPackages.express
      requiredPackages.body-parser
      (ruby.withPackages (ps: [ ps.nokogiri ]))
    ];
  };
  wrapHost = ssl: host: (if ssl then "https" else "http") + "//${host}";
in
  {
    english = settings: website {
      ssl = settings.ssl or false;
      drafts = settings.drafts or false;
      source = blog-source;
      path = ".";
      replaceUrl = {
        from = "https://danilafe.com";
        to = wrapHost (settings.ssl or false) settings.host;
      };
    };
    russian = settings: website {
      ssl = settings.ssl or false;
      drafts = settings.drafts or false;
      source = blog-source-localized;
      path = "ru";
      replaceUrl = {
        from = "https://ru.danilafe.com";
        to = wrapHost (settings.ssl or false) settings.host;
      };
    };
  }